Spojový seznam - odebrání prvku/prvků s maximální hodnotou – Pascal – Fórum – Programujte.com

Ahoj,

snažím se vytvořit proceduru, která by mi měla ze spojového seznamu vynechat všechny prvky, které osahují maximální hodnotu z celého seznamu.

Něco jsem napsal, ale procedura mi padá:

type Ukazatel = ^Prvek;
     Prvek = record Dalsi: Ukazatel;
                    Hodnota: integer;
             end;

procedure Vynech_nejvetsi;
          var Pomocna,Pruchod,Zacatek,Konec: Ukazatel;
              Nejvetsi: integer;
          begin
               while Pomocna <> nil do
                                  Pomocna:= Zacatek;
                                  if Pomocna^.Dalsi^.Hodnota > Pomocna^.Hodnota then Nejvetsi:= Pomocna^.Dalsi^.Hodnota;
               while Pomocna <> nil do
                                  Pruchod:= Pomocna^.Dalsi;
                                  if Pomocna^.Hodnota = Nejvetsi then begin
                                                                           if Konec = Zacatek then
                                                                                                  while Pomocna <> nil do begin
                                                                                                                               dispose(Konec);
                                                                                                                               Zacatek:= nil;
                                                                                                                               Konec:= nil;
                                                                                                                          end
                                                                                              else if Konec <> Zacatek then
                                                                                                                           while Pomocna <> nil do begin
                                                                                                                                                        Pruchod:= Zacatek;
                                                                                                                                                        Zacatek:= Zacatek^.Dalsi;
                                                                                                                                                        dispose(Pruchod);
                                                                                                                                                        Pruchod:= nil;
                                                                                                                                                   end
                                                                  else if Pruchod^.Hodnota = Nejvetsi then begin
                                                                                                                Pruchod:= Pomocna^.Dalsi;
                                                                                        Pomocna^.Dalsi:= Pruchod^.Dalsi;
                                                                                        dispose(Pruchod);
                                                                                                           end;
                                                                      end;
          end;

Už si nevím rady. Poradil byste mi někdo prosím? Předem moc děkuji.
 

#1 arden89
pro příště vkládej kód pomocí menu "<?"

1. na začátku procedury, je potřeba vložit do proměnné Zacatek ukazatel na první prvek (ideálně jako vstupní parametr procedury), ten si musíš v programu nějak zapamatova jinak to ztrácí smysl.

2. a v prvním while bys měl testovat Pomocna^.Dalsi <> nill

Děkuji za rady. Proceduru jsem se pokusil upravit:

procedure Vynech_nejvetsi;

var Pomocna, Pruchod, Zacatek: Ukazatel;
    Nejvetsi: integer;

begin

while Pomocna^.Dalsi <> nil do begin
                              Pomocna:= Zacatek;
 if Pomocna^.Dalsi^.Hodnota > Pomocna^.Hodnota then Nejvetsi:= Pomocna^.Dalsi^.Hodnota;
                               end;

while Pomocna <> nil do begin
                       Pruchod:= Pomocna;
                       if Pomocna^.Hodnota = Nejvetsi then begin
							      Pomocna:= Pruchod^.Dalsi;
                                                              Pruchod^:= Pomocna^;
                                                              Pruchod:= Pomocna^.Dalsi;                                                                      
                                                              dispose(Pomocna);
                                                              Pomocna:= Pruchod;
                                                           end
                                                      else begin
                                                              Pomocna:= Pomocna^.Dalsi;
                                                              Pruchod:= Pomocna;
                                                           end;

                        end;
end;

Takto mi to dává smysl, přesto to ale nefunguje. Nevíte prosím, co dělám špatně?

Děkuji

Těm proměnným musíš nejdřív nastavit nějakou hodnotu a přinejmenším Zacatek bude asi parametr té procedury.

procedure Vynech_nejvetsi(var Zacatek: Ukazatel);
var
    Pruchod, Predchozi, Dalsi: Ukazatel;
    Nejvetsi: integer;
begin
    if Zacatek = nil then
        Exit;

    Nejvetsi := Zacatek^.Hodnota;
    Pruchod := Zacatek^.Dalsi;
    while Pruchod <> nil do begin
        if Pruchod^.Hodnota > Nejvetsi then
            Nejvetsi := Pruchod^.Hodnota;
        Pruchod := Pruchod^.Dalsi;
    end;

    Predchozi := nil;
    Pruchod := Zacatek;
    while Pruchod <> nil do begin
        Dalsi := Pruchod^.Dalsi;

        if Pruchod^.Hodnota = Nejvetsi then begin
            Dispose(Pruchod);
            if Predchozi <> nil then
                Predchozi^.Dalsi := Dalsi;
            if Pruchod = Zacatek then
                Zacatek := Dalsi;
        end
        else begin
            Predchozi := Pruchod;
        end;

        Pruchod := Dalsi;
    end;
end;

#4 gna
Díky moc, proceduru jsem si podle tvého návrhu upravil a funguje.