Matice - sloupec s největším průměrem – Pascal – Fórum – Programujte.com

Je zadaná matice n*n a mám zjistit, sloupec s největším průměrem.
V Pascalu jsem vypotil toto:

program UKOL;

var a:array[1..100,1..100] of integer;
    i,j,n:integer;
    prum:real;
begin
      write('Zadej rozměr matice: ');
      readln(n);
      for i:=1 to n do
         for j:=1 to n do begin
                             write('Zadej prvek [',i,',',j,']: ');
                             readln(a[i,j]);
                          end;
      for j:=1 to n do
        for i:1 to n do begin
                            prum:=(prum+a[j,i])/n;
                            writeln('Průměr ',j,'. sloupce je ',s:6:2);
                            s:=0;
                        end;
readln;
end.

Zadám matici 2x2 s prvky [1,1]: 2
                                      [1,2]: 5
                                      [2,1]: 3
                                      [2,2]: 8
a vypíše to tohle:
Průměr 1. sloupce je: 1.00
Průměr 1. sloupce je: 2.50
Průměr 2. sloupce je: 1.50
Průměr 2. sloupce je: 4.00

Poradíte mi prosím, co tam změnit?

To, co jsi sem postnul, má několik chyb, takže to nelze přeložit. To za prvé. A za druhé - ujasni si, jak se vůbec průměr počítá, protože to, co tam počítáš, určitě není průměr, a už vůbec ne sloupce. Ale abych jenom neprudil... na rychlo smatlaný v delphi (nejsou ošetřený chyby atp.):

program UKOL;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Math;

var
  Matrix:         Array of Array of Integer;  //hlavni matice
  MatrixSize:     LongWord;                   //zadana velikost matice
  ColumnAverage:  Double;                     //prumer sloupce
  LargestAverage: Double;                     //nejvetsi zaznamenany prumer
  ColumnSum:      Int64;                      //soucet prvku sloupce
  Column, Row:    Integer;                    //promenne cyklu
  Result:         LongWord;                   //vysledek (cislo sloupce)

begin
Write('Zadejte rozmer matice (n*n): '); ReadLn(MatrixSize);
SetLength(Matrix,MatrixSize,MatrixSize);
{- Zadavani hodnot ------------------------------------------------------------}
For Row := 0 to (MatrixSize - 1) do
  For Column := 0 to (MatrixSize - 1) do
    begin
      Write('Zadejte prvek [' + IntToStr(Column + 1) + ', ' +
        IntToStr(Row + 1) + ']: ');
      ReadLn(Matrix[Column,Row]);
    end;
{- Vypocet --------------------------------------------------------------------}
LargestAverage := MinDouble;
Result := 0;
For Column := 0 to (MatrixSize - 1) do
  begin
    ColumnSum := 0;
    For Row := 0 to (MatrixSize - 1) do
      Inc(ColumnSum,Matrix[Column,Row]);
    ColumnAverage := ColumnSum / MatrixSize;
    If ColumnAverage > LargestAverage then
      begin
        LargestAverage := ColumnAverage;
        Result := Column;
      end;
  end;
{- Vypis vysledku -------------------------------------------------------------}
WriteLn;
WriteLn('Nejvetsi prumer ma sloupec ' + IntToStr(Result + 1) + ' (' +
  FloatToStr(RoundTo(LargestAverage,-5)) + ')');
WriteLn;
Write('Stiskni enter pro ukonceni programu...'); ReadLn;
end.

Můžeš se inspirovat.

#2 Sniper

Abychom Lukáše nemátli: po syntaktické stránce je ten jeho program v pořádku, v TP nebo FP půjde přeložit i spustit.
S tím ostatním máš samozřejmě pravdu.