Vlozeni prvku na konec seznamu – Pascal – Fórum – Programujte.com

Prosim o radu mel jsem za ukol vkladat do lin. seznamu unikatni real hodnoty. Ale nemuzu prijit na proceduru ktera ten prvek ulozi na konec.

type UkPrvek = ^Prvek;

     Prvek = record

               Data: real;

               Dalsi: UkPrvek;

     end;

function vyhledejHodnotu(var S:UkPrvek; hodnota:real): boolean;

var pom:UkPrvek;

    vyhodnoceni: boolean;

begin

    pom:=S;

    vyhodnoceni:=false;

    while (pom <> nil) do

      begin

        if (pom^.Data = hodnota) then vyhodnoceni:=true;

        pom:=pom^.Dalsi

      end;

    vyhledejHodnotu:=vyhodnoceni

end;

procedure pridejUnikatni(var S: UkPrvek; hodnota:real);

var pom:UkPrvek;

begin

  if vyhledejHodnotu(S,hodnota) then exit

  else

      begin

       new(pom);

       pom^.Data:=hodnota;

       pom^.Dalsi:=S;

       S:=pom;

      end;

end;

#1 sparky29
Pokud funkce vyhledejHodnotu nebyla požadována, tak z ní udělej rovnou proceduru pridejUnikatni, protože přece když prohledáš celý seznam aniž bys ji našel, tak jsi na jeho konci a můžeš tam tu nenalezenou unikátní hodnotu přidat (jen trošku polaď to procházení, buď si vždy někam ulož předchozí ukazatel, nebo poslední hodnotu testuj zvlášť - to zvládneš ne?). A pokud byla požadována, tak použij její mírně modifikovaný kód v té proceduře.

http://pastebin.com/unF0XN6e

pozadovana nebyla, ale nevim jak jinak bych to vlozil nakonec

type

  UkPrvek = ^Prvek;

  Prvek = record

    Data: real;

    Dalsi: UkPrvek

  end;

procedure pridejNaKonec(var S: UkPrvek; hodnota: real);

var

  pom: UkPrvek;

  nalezeno: boolean;

begin

  pom:= S;

  nalezeno:=true;

  while (pom<>nil) and nalezeno do begin

    if pom^.Data=hodnota then

      nalezeno:=false

    else

      pom:=pom^.Dalsi;

    end;

    if nalezeno then

      pom^.Data:=hodnota;

end;

procedure kontrola(var S:UkPrvek);

var pom: UkPrvek;

begin

  pom:=S;

  while (pom <> nil) do begin

    write(pom^.Data:2:2,'; ');

    pom:=pom^.Dalsi;

    end;

end;

var S:UkPrvek;

begin

pridejNaKonec(S,3.1);

pridejNaKonec(S,3.4);

pridejNaKonec(S,7.2);

pridejNaKonec(S,3.1);

kontrola(S);

end.

ale nehazi mi to pekny hodnoty a hodi to runtime error 216

#5 sparky29
A co takhle zabírat dynamické proměnné na haldě? (A pak po sobě uklízet?)

Co nastavování výchozích hodnot (včetně ukazatele na další prvek?)

A neškodily by komentáře co kde děláš....

A v neposlední řadě zkus příště nazývat proměnné pravými jmény, nalezeno/nenalezeno.

Nemám teď čas tě vést za ruku krok za krokem, tak prozkoumej jak by to třeba mohlo být a zjisti, kde máš nedostatky:

type

  UkPrvek = ^Prvek;
  Prvek = record
    Data: real;
    Dalsi: UkPrvek
  end;

procedure pridejNaKonec(var S: UkPrvek; hodnota: real);
var
  pom,predchozi: UkPrvek;
  nenalezeno: boolean;
begin
  pom:= S;
  predchozi:=nil;
  nenalezeno:=true;
  if pom<>nil
     then
         begin
         {Seznam není prázdný, můžeme hledat}
           while (pom<>nil) and nenalezeno do
             begin
               if pom^.Data=hodnota then nenalezeno:=false;
               predchozi:=pom;
               pom:=pom^.Dalsi;
             end;
           if nenalezeno then
             begin
		{Nic jsme nenašli, musíme vytvořit nový prvek 
		a zařadit ho na konec - neboli za předchozí}
               new(pom);
               pom^.Data:=hodnota;
               pom^.Dalsi:=nil;
               predchozi^.Dalsi:=pom;
             end;
         end
     else
       begin
         {Seznam byl prázdný, musíme založit nový}
         new(pom);
         pom^.Data:=hodnota;
         pom^.Dalsi:=nil;
         S:=pom;
       end;

end;

procedure kontrola(var S:UkPrvek);
var pom: UkPrvek;
begin
  pom:=S;
  while (pom <> nil) do begin
    write(pom^.Data:2:2,'; ');
    pom:=pom^.Dalsi;
  end;
end;

var S:UkPrvek;

begin
S:=nil;
pridejNaKonec(S,3.1);
pridejNaKonec(S,3.4);
pridejNaKonec(S,7.2);
pridejNaKonec(S,3.1);
pridejNaKonec(S,7.2);
pridejNaKonec(S,3.5);
kontrola(S);
end.

Diky moc pokusim se to projit a priste davat komentare

#7 sparky29
Jasně, a až to projdeš přidej ještě proceduru na uvolnění paměti...

procedure uklid(var S: UkPrvek);
var pom, nasmazani: UkPrvek;
begin
 pom:=S;
 while pom <> nil do begin
  nasmazani:=pom;
  pom:=pom^.dalsi;
  dispose(nasmazani);
 end;
 S:=nil;
end;