Výpis dat do tabulky – Visual Basic – Fórum – Programujte.com

Ahoj, chtěla bych se zeptat na programování v Excelu ve VBA. Můj projekt vypadá tak, že když zapnu excel na stránce bude tabulka a nad ní tlačítko přidej kontakt. Když kliknu na tlačítko zobrazí se tabulka kde se zaškrtne pohlaví, zapíše příjmení a jméno, bydliště, email atd atd. A když kliknu na OK mělo by se to všechno zaznamenat do tabulky. Jediné co mi funguje je spuštění tabulky, ale text se mi už neukládá. Nevíte někdo co s tím? Moc děkuju za pomoc

Myslíš něco takovýho?

List1: 

Option Explicit

Private Sub CommandButton1_Click()
    Call UserForm1.Init
End Sub

UserForm1:

Option Explicit

Dim intRadek As Integer

Private Sub cmd1_Click()
    
    Me.Hide
    
    If opt1.Value = True Then
        List1.Cells(intRadek, 2) = "Muž"
    
    Else
        List1.Cells(intRadek, 2) = "Žena"
    
    End If
    
    List1.Cells(intRadek, 3) = txt1.Text
    List1.Cells(intRadek, 4) = txt2.Text
    List1.Cells(intRadek, 5) = txt3.Text
    List1.Cells(intRadek, 6) = txt4.Text
    
End Sub

Private Sub cmd2_Click()
    
    Me.Hide

End Sub

Public Sub Init()

    intRadek = 0
    
    Dim i As Long
    
    For i = 6 To 65536
        If List1.Cells(i, 2) = vbNullString Then
            intRadek = i
            Exit For
        End If
    Next

    If intRadek = 0 Then
        MsgBox "Už není volné místo v tabulce.", vbCritical
        Exit Sub
    
    Else
        opt1.Value = True
        opt2.Value = False
        txt1.Text = vbNullString
        txt2.Text = vbNullString
        txt3.Text = vbNullString
        txt4.Text = vbNullString
        Me.Show
    
    End If

End Sub

Private Sub opt1_Click()
    
    If opt1.Value = True Then
        opt2.Value = False
    
    Else
        opt2.Value = True
    
    End If

End Sub

Private Sub opt2_Click()
    
    If opt2.Value = True Then
        opt1.Value = False
    
    Else
        opt1.Value = True
    
    End If

End Sub

Ještě oprava.

Namísto "Dim intRadek As Integer" bude lepší "Dim intRadek As Long", protože do Integeru se nedá uložit větší číslo než 32767, jinak vznikne Overflow.