Pomos s podprogramem – Pascal – Fórum – Programujte.com

Potřeboval bych poradit jak tohle přesně udělat(matici mxn naplnit náhodnými čísly od 1 do 99,urči podprogramem součet prvku prvního sloupce a součet prvku posledního sloupce,zjisti který součet je nejnižši,zobraz matici)Tohle mám hotové prakticky se dá říct že všechno jen nevím jak s těmi podprogramy :/

program matice;
uses crt;
var a:array[1..10,1..10] of integer;
    m,n,i,j,s,r,sums,sumr:integer;
begin
clrscr;
write('Zadej pocet radku matice:');
readln(m);
write('Zadej pocet sloupcu matice:');
readln(n);
randomize;
sums:=0;
sumr:=0;
write('Zadej sloupec matice pro soucet:');
readln(r);
if r>m then begin writeln('Zadej znovu cislo sloupce musi byt mensi nez ',m+1);
readln(r);
end;
write('Zadej sloupec matice pro soucet:');
readln(s);
if s>n then begin writeln('Zadej znovu cislo sloupce musi byt mensi nez ',n+1);
readln(s);
end;
for i:=1 to m do for j:=1 to n do a[i,j]:=random(99)+1;
for i:=1 to n do sumr:=sumr+a[i,r];
for i:=1 to m do sums:=sums+a[i,s];
for i:=1 to n do begin for j:=1 to n do write(a[i,j]:8);
writeln;
   end;
writeln('Soucet prvku ',r,'. sloupce je:',sumr);
writeln('Soucet prvku ',s,'. sloupce je:',sums);
readln;
if sums>sumr
then
write('Prvni sloupec je mensi nez posledni')
else write('Posledni sloupec je mensi nez prvni');
writeln;
readln;
  end.

type
    TMatice = array of array of integer;

function vygeneruj(vyska, sirka: integer): TMatice;
var
    matice: TMatice;
    radek, sloupec: integer;
begin
    setlength(matice, vyska, sirka);
    for radek := low(matice) to high(matice) do
        for sloupec := low(matice[radek]) to high(matice[radek]) do
            matice[radek,sloupec] := random(5) + 1;
    vygeneruj := matice;
end;

function secti_sloupec(matice: TMatice; sloupec: integer): integer;
var
    radek, soucet: integer;
begin
    soucet := 0;
    for radek := low(matice) to high(matice) do
        soucet := soucet + matice[radek,sloupec];
    secti_sloupec := soucet;
end;

procedure vypis(matice: TMatice);
var
    radek, sloupec: integer;
begin
    for radek := low(matice) to high(matice) do
        begin
            for sloupec := low(matice[radek]) to high(matice[radek]) do
                write(matice[radek,sloupec]:3);
            writeln;
        end;
end;

var
    matice: TMatice;
    prvni, posledni: integer;

begin
    matice := vygeneruj(4, 5);
    vypis(matice);

    prvni    := secti_sloupec(matice, low(matice[0]));
    posledni := secti_sloupec(matice, high(matice[0]));
    writeln('prvni    ', prvni);
    writeln('posledni ', posledni);
end.