Rozparsování řetězce – Delphi – Fórum – Programujte.com

Mám v souboru txt jeden řádek:

1;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;1

ten načtu a rozparsuju a ve výsledku  Self.FiltryCheckedList obsahuje jen dvě položky (
Self.FiltryCheckedList.count=2). Jak je to možné? Jak to opravit?
 

readln(f, Self.FiltryChecked );
Self.FiltryCheckedList := TStringList.create;
if ( length(Self.FiltryChecked)>0 ) then
     ExtractStrings([';'],[],PChar(Self.FiltryChecked), Self.FiltryCheckedList);


Self.FiltryCheckedList.count = 2 !!!

#1 oxidián
duplicity, jsem ti to psal několikrát

jeden ze stringů bude "1" druhý bude prázdný řetězec

Tak jsem zjistil, že extractstrings nepustí prázdné řetězce do výstupu... Čím to teda rozparsovat? Je na to funkce?

Jak rozjet .Split?

Self.FiltryChecked.Split(';');

[Error] testy.pas(284): Record, object or class type required ... Self.FiltryChecked.
 

#3 oxidián
já na to mám v tý mojí knihovně Typ a funkci

TArrayOfString : array of string;  - stejné používání jako normální Array

function TextParser(separator, text: string): TArrayOfString;
var
  poz, cnt, lenSep: integer;
begin
  SetLength(result, 0);
  lenSep := length(separator);

///prázdný řetězec vrátí prázdné pole
  if length(text) = 0 then
    exit;            

//separátor prázdný nebo delší než text vrátí v poli (index 0) text
  if (lenSep = 0) or (lenSep > length(text)) then
  begin
    SetLength(result, 1);
    result[0] := text;
    exit;            
  end;

//nastavení délky pole na počet znaků řetězce, což je max. možný
//počet substringů, možná by se dalo použít na prázdný separátor, 
//kdy by se text rozsekal do pole znaků po 1
  SetLength(result, length(text));   
  cnt := 0;
  poz := 0;

  repeat

//prázdno za posledním separátorem
    if length(text) = 0 then
    begin
      result[cnt] := '';
      inc(cnt);
      break;
    end;
    
//zjisti pozici separatoru, když není další vlož do pole zbytek řetězce    
    poz := pos(separator, text);
    if poz = 0 then
      result[cnt] := text
    else
    begin
//tato podmínka je třeba kvůli více zn. separátorům
      if length(text) >= poz then   
      begin
//separátor na začátku, vlož prázdný
        if poz = 1 then
          result[cnt] := ''
        else
//jinak zkopíruj do pole začátek po separátor
          result[cnt] := Copy(text, 1, poz - 1);
      end;
//smaž začátek včetně celého separátoru
      delete(text, 1, poz + lenSep - 1);
    end;

    inc(cnt);        //inkrementace counteru pole
  until poz = 0;

//uprav-zmenši na skutečnou velikost pole
  SetLength(result, cnt);     
end;

jsou tam ošetřené snad všechny myslitelné situace, od víceznakových oddělovačů, po prázdné řetězce včetně prázdného za posledním oddělovačem a je to včetně duplicit.

EDIT: Okomentoval jsem pro tebe tu funkci, abys případně věděl co a jak to dělá

a přesunul upravil jsem 2 řádky jen pro přehlednost, funkční byla i původní verze.

No jó, ale já nechci psát složitou funkci. Když tam už existuje ta funkce .Split, tak bych ji raději použil.

#6 oxidián
v tom splitu máš chybu separátor se zadává jako array tzn ...split([';']);

FiltryCheckedList : TArray<string>;    -  Otázkou je jestli tvoje verze Delphi podporuje TArray

FiltryCheckedList := FiltryChecked.Split([';']);

#7 MilanL
navíc nevím jak se to chová při prázdných hodnotách

funkci psát nemusíš použij (zkopíruj) si tu mojí, ti to dovolím, nelpím na autorských právech :D

#6 oxidián
Na té funkci není nic složitého a kdybys občas něco vypotil, tak by ses možná něco naučil. Ale máš to štěstí, že nic psát nemusíš, protože to ten list už umí. A používej dokumentaci ke své verzi Delphi.

slist.Delimiter := ';';
slist.StrictDelimiter := true;
slist.DelimitedText := '1;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;1';

#8 MilanL
A když jsi dopisoval ty komentáře, tak ti to vůbec nepřišlo divný? Proč je v blbé funkci na postupné hledání oddělovačů ŠEST IFů?

function split(str: string; sep: string): tstringlist;
var
    sl: tstringlist;
    seppos, sublen: sizeint;
begin
    sl := tstringlist.create;
    repeat
        seppos := pos(sep, str);
        sublen := seppos - 1;
        if sublen = -1 then
            sublen := length(str);
        sl.add(copy(str, 1, sublen));
        delete(str, 1, sublen + length(sep));
    until seppos = 0;
    split := sl;
end;

To jsem nevěděl, že je to tak jednoduchý

readln(f, Self.FiltryChecked );
Self.FiltryCheckedList := TStringList.create;
if ( length(Self.FiltryChecked)>0 ) then
  begin
     Self.FiltryCheckedList.Delimiter       := ';';
     Self.FiltryCheckedList.DelimitedText   := Self.FiltryChecked;
     // Self.FiltryCheckedList
  end;

https://stackoverflow.com/questions/1335027/delphi-stringlist-delimiter-is-always-a-space-character-even-if-delimiter-is-se

dík gna