Minimalizace ikony do hl. panelu – Visual Basic – Fórum – Programujte.com

Ahoj poradí mi někdo jak minimalizovat ikonu projektu do hlavniho panelu ?

Pro zobrazení ikony do SysTray

TrayIcon.cbSize = Len(TrayIcon)
TrayIcon.hwnd = Me.hwnd
TrayIcon.uID = 0
TrayIcon.uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
TrayIcon.uCallbackMessage = WM_MOUSEMOVE
Me.Icon = Me.Image1.Picture
TrayIcon.hIcon = Me.Icon
TrayIcon.szTip = "RMouse = Nastavení" & vbCrLf & _
"LMouse = Konec"
RetVal = Shell_NotifyIcon(NIM_ADD, TrayIcon)

Pro změnu ikony zobrazené v SysTray

TrayIcon.cbSize = Len(TrayIcon)
TrayIcon.uID = 0
TrayIcon.uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
TrayIcon.hIcon = Me.Image2.Picture
TrayIcon.szTip = "Přihlášení do NoVB" & vbCrLf & "Sledování uživatelů" & vbCrLf & "Archivace dat a zdrojů"
RetVal = Shell_NotifyIcon(NIM_MODIFY, TrayIcon)

Pro vymazání ikony ze Systray

TrayIcon.cbSize = Len(TrayIcon)
TrayIcon.hwnd = Me.hwnd
TrayIcon.uID = 0
TrayIcon.uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
RetVal = Shell_NotifyIcon(NIM_DELETE, TrayIcon)

Pro ošetření kliknutí na ikonku v SysTray

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim ProShell As Variant
RetVal = x / Screen.TwipsPerPixelX
Select Case RetVal
Case WM_LBUTTONDOWN 'reakce na levou myš
Me.Show
Me.Refresh
Me.WindowState = vbMinimized
End
Case WM_RBUTTONDOWN 'reakce na pravou myš
Me.Show
Me.Refresh
End Select
End Sub

potřebné deklarace
pro položení do SysTray

Public Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long
Public Type NOTIFYICONDATA
cbSize As Long
hwnd As Long
uID As Long
uFlags As Long
uCallbackMessage As Long
hIcon As Long
szTip As String * 64
End Type
Public TrayIcon As NOTIFYICONDATA
Public Const NIF_MESSAGE = &H1
Public Const NIF_TIP = &H4
Public Const NIF_ICON = &H2
Public Const NIM_ADD = &H0
Public Const NIM_MODIFY = &H1
Public Const NIM_DELETE = &H2

pro klepnutí myši na ikonu v SysTray
Public Const WM_MOUSEMOVE = &H200
Public Const WM_LBUTTONDBLCLK = &H203
Public Const WM_LBUTTONDOWN As Long = &H201
Public Const WM_RBUTTONDOWN = &H204
Public Const WM_MBUTTONDOWN = &H207
Public RetVal As Long