Delphi II - 9. lekce

Dnes budeme pokračovat v práci na našem MP3 přehrávači – uděláme playlist a ukážeme si práci s INI soubory.

No a je tu další díl. Pamatujete si ještě na náš MP3 přehrávač ze 7. lekce? Doufám, že jste si svůj výtvor uložili, abyste ho nemuseli znovu tvořit od začátku. Pokud ho nemáte, mám pro vás tu smutnou zprávu, že ho budete muset udělat.

Pro svůj dnešní výtvor použijeme původní přehrávač (doporučuji si vytvořit kopii toho, co jste vytvořili v 7. lekci, abyste se k němu mohli případně vrátit).

Návrh uživatelského prostředí

Seznam komponent

Z formuláře naopak smažte komponentu soubor a její popisku Label1. Ty nebudeme potřebovat.

Pozn.: Ze začátku je možné, že program nepůjde přeložit – to je v pořádku, do konce článku to vyřešíme.

Náš formulář může nyní vypadat dejme tomu takto:

A teď je na místě podívat se na naši novou komponetu: ListBox

ListBox

ListBox slouží k vytváření seznamů. Každá položka je typu string a nachazí se v ListBox.Items.Strings[index_polozky], kde index_polozky je typu integer a obsahuje pořadové číslo položky.

Pozor! Položky se číslují od 0 (to platí obecně pro všechny programovací jazyky a pro počítače), to znamená, že první položka má index 0, druhá 1, třetí má 2 atd.

Programujeme!

Tak jdeme na to. Nejprve je nutné přidat do USES knihovnu INIFiles. Dalším krokem bude naprogramování procedury onCreate hlavního formuláře:

procedure TForm1.FormCreate(Sender: TObject);
var ini: TIniFile;
    skladby: TStringList;
    i: integer;
begin
  ini:=TIniFile.Create(ExtractFilePath(Application.ExeName)+'\nastaveni.ini');
    //otevře, popř. vytvoří, INI soubor nastaveni.ini v adresáři s aplikací
  skladby:=TStringList.Create; //vytvoříme si dočasný seznam
  ini.ReadSection('skladby',skladby); //načteme do něj seznam všech položek v dané sekci INI
  for i:=0 to skladby.Count-1 do
    playlist.Items.Add(ini.ReadString('skladby',skladby.Strings[i],''));
      //do playlistu nahrajeme z INI souboru hodnotu každé položky v dočasném seznamu
  playlist.ItemIndex:=ini.ReadInteger('ostatni','aktualni',0);
  skladby.Free; //uvolníme dočasný seznam
  ini.Free; //a ini soubor
  prehravac:=TMediaPlayer.Create(Form1); //vytvoří novou instanci objektu TMediaPlayer
  prehravac.Parent:=Form1; //nastaví vlastníka komponenty
  prehravac.Visible:=false; //a skryje ji
end;

Teď si ještě vysvětlíme, jak co funguje. S INI souborem se pracuje jako s objektem. Tomu napovídá i způsob otevření pomocí TIniFile.Create(soubor: string). Stejně jako u ostatních objektů je ho nutné uzavřít zase stejně jako objekt, tedy přes metodu Free.

Pokud chceme číst z INI souboru, musíme rozlišit datové typy:

Co se zápisu týče, je to zcela stejné, pouze Read je nahrazeno Write, ale o tom později. Zde je syntaxe čtecích funkcí (kromě ReadSection a ReadSections):

  Read[typ](sekce: String, plozka: string, vychozi_hodnota: [typ]): [typ];

Kde [typ] nehrazuje daný datový typ, sekce označuje název sekce v daném INI souboru a polozka název položky. Vychozi_hodnota je stejného typu, jako je čtený typ, a její hodnota je vrácena, pokud daná sekce nebo položka není v INI souboru nalezena. Celá funkce pak vrací data v datovém typu [typ]

Pro proceduru ReadSection je syntaxe:

  ReadSection(sekce: string, vystup: TStrings);

Kde sekce je název sekce a vystup vrací seznam všech položek z dané sekce.

Procedura ReadSections:

  ReadSections(vystup: TStrings);

Kde vystup vrací seznam všech sekcí v daném souboru.

Dalším krokem, který dnes podnikneme, bude naprogramování tlačítka pro přidání souborů do playlistu.

Vytvoříme tedy událost onClick tlačítka pridat_soubor_btn. Celkově procedura bude obsahovat dva řádky – otevření dialogu opendialog a přiřazení seznamu souborů do playlistu pomocí funkce:

    playlist.Items.AddStrings(opendialog.files);

Další událostí je událost onClick tlačítka vyprazdnit_playlist_btn, kde nám stačí jeden řádek s funkcí playlist.clear.

Události, které musíme obsloužit jako další, jsou onClick pro tlačítka predchozi_btn a dalsi_btn. Obě procedury budou prakticky stejné, lišit se budou jen v jednom.

  playlist.ItemIndex:=playlist.ItemIndex-1; //vybere předcházející položku
  if playlist.ItemIndex=-1 then playlist.ItemIndex:=0; //pokud vybral položku -1 tak vy
  if prehrat_btn.Caption='Pauza' then begin //pokud probíhá přehrávání
    prehrat_btn.Caption:='Přehrát'; //tak ho "přerušíme"
    prehrat_btnClick(Sender); //a začneme přehrávat znovu, ale teď už se načte
      //předchozí písnička
  end;

Tohle je kód pro predchozi_btnClick. U procedury dalsi_btnClick pouze změníme na prvním řádku -1 na +1.

Teď bude nutné provést něco s dvojklikem na nějakou položku v playlistu. Pro tento případ je tady událost onDblClick. Obsah procedury playlistDblClick:

    prehrat_btn.Caption:='Přehrát'; //"přerušíme" přehrávání
    prehrat_btnClick(Sender); //a začneme přehrávat znovu, tentokrát se načte vybraná písnička

Jednoduché, bez nutnosti dále komentovat.

Na závěr je potřeba zapsat některé informace do souboru s nastavením. Zde je celá procedura k události OnClose formuláře:

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
var ini: TIniFile;
    i: integer;
begin
  prehravac.Free; //uvolní komponentu přehrávače z paměti
   //otevřeme INI soubor
  ini:=TIniFile.Create(ExtractFilePath(Application.ExeName)+'\nastaveni.ini');
   //odstraníme všechny skladby z playlistu a zapíšeme ho celý znovu
  ini.EraseSection('skladby');
   //postupně do něj zapíšeme seznam všech skladeb formou INDEX_SKLADBY=cesta_k_souboru
  for i:=0 to playlist.Items.Count-1 do begin
    ini.WriteString('skladby',IntToStr(i),playlist.Items.Strings[i]);
  end;
   //ještě zapsat posldní přehrávanou položku
  ini.WriteInteger('ostatni','aktualni',playlist.ItemIndex);
   //a konec
  ini.Free;
end;

Zde, jak jsem slíbil někde nahoře, se pozastavím u funkce pro zápis do INI souboru. S funkcemi pro zápis se manipuluje stejně jako se čtecími funkcemi, akorát je vynechána poslední proměnná. Pro zápis neexistují funkce WriteSection a WriteSections.

A nakonec je ještě potřeba provést drobnou úpravu v proceduře prehrat_btnClick, kde musíme upravit způsob získání názvu souboru, který se bude přehrávat:

Odstraňte tyto kusy kódu:

    if soubor.Text='' then begin
      MessageDlg('Nebyl zadán soubor',mtError,[mbOK],0);
      Exit;
    end;
    if not FileExists(soubor.Text) then begin
      MessageDlg('Zadaný soubor neexistuje',mtError,[mbOK],0);
      Exit;
    end;
    ...
    soubor.Enabled:=false;

A tímto kódem nahraďte řádek, který začíná stejně (tedy prehravac.FileName:=):

 ...
 prehravac.FileName:=playlist.Items.Strings[playlist.ItemIndex];
 ...

Z procedur zastavit_btnClick a casovacTimer pak odstraňte následující řádek:

  soubor.Enabled:=true;

Závěr

Přehrávač má stále ještě mnoho chyb: po skončení písničky se nezačne přehrávat další, nelze přidávat kompletní adresáře, playlist neumí číst ID tagy atd. To vše samozřejmě vyřešíme v dalším díle, takže se, prosím vás, neptejte, jak se to dělá, dozvíte se to :-) Příště necháme přehrávač a zase se vrátíme k textovému editoru – přidáme panel nástrojů a naučíme náš editor několika novým kouskům.

Úkol

Věřím, že jste se na něj těšili stejně jako já na jeho vymýšlení.

Vytvořte program, kde budou dva listboxy (vedle sebe) a čtyři tlačítka pod sebou (mezi těmi listboxy). Kliknutím na první tlačítko se všechny položky z 1. listboxu přesunou do listboxu druhého. Kliknutím na druhé tlačítko se tam přesune pouze jedna položka, ta, která je zrovna vybraná (nezapomeňte ošetřit případ, kdy není označena žádná položka). Zbylá dvě tlačítka provádí to samé, akorát přesouvají data z 2. do 1. listboxu.

Dodatek

Ještě tu mám dotaz na linuxáky. Byl by zájem o doplňkové články o programování v ObjectPascalu v programu Lazarus? Pokud ano, pište mi na e-mail, ICQ nebo formou úkolů. Články budu psát jen při dostatečném množství zájemců!

Stejný dotaz jsem hodil i do fóra, takže nemusíte odpovídat dvakrát ;-)