Jak přiřadit hodnotu konstatně? – Pascal – Fórum – Programujte.com

Dobrý den, ve svém programu (který je již hotový) mám definovanou konstatnu

const MAX=100

a definovaný styl

type string_MAX=string[MAX];  

jenže po dokončení programu jsem si uvědomil, že budu muset konstatnu MAX měnit podle zadání uživatele.

Zajímalo by mě, jak by se toto dalo udělat?

Představuji si to tak že:

Program se zeptá, kolik má být MAX (např 59) a tato hodnota se zapíše do const MAX, která se teprve poté doplní do všech dalších funkcí, procedur a zbytku probramu včetně typedef.

Děkuji mnohokrát za rady.

pokud to ma jit menit za behu, tak tude cesta nevede... vsechno se to vyhodnoti uz v dobe prekladu a pak uz s tim nehnes... (maximalne si muzes udelat pole o maximalnim poctu prvku treba 1000.. a uzivatel by zadal jen pocet prvku)

Nemusí se měnit za běhu, jen jí musí uživatel sám zvolit na začátku programu. Dál už bude všude stejná.

jenze to uz splnuje pojem "za behu"

kazdopadne bud se zamerit na dynamickou pamet nebo mit urcitej limit nad, ktery uzivatel nebude moci jit.. at uz zada cokoliv

A neslo by třeba využít nějak globální proměnné (nevím zda je to správný pojem)?

že bych si na začátku programu vytvořil globální proměnou MAX ke které by se dalo poté přistupovat i z funkcí a všech částí programu?

da, ma to ale svoje "ale" - napriklad ze nesmis presahnout misto, ktere mas v poli (bud to zacne padat nebo prepisovat data za polem)

Děkuji, a jak toho docílím?

Toto by snad mělo fungovat ve všem kompatibilním s Turbo Pascalem.

const
  MAX = 10000;

type
  TPole = array [1..MAX] of integer;
  PPole = ^TPole;

var
  pole: PPole;
  pole_pocet_prvku, pole_velikost_pameti, i: longint;

begin
  pole_pocet_prvku := 5000;

  if pole_pocet_prvku > MAX then
  begin
    writeln('To je moc! (max ', MAX, ')');
    exit;
  end;

  pole_velikost_pameti := pole_pocet_prvku * sizeof(integer);

  if pole_velikost_pameti > maxavail then
  begin
    writeln('Nedostatek pameti! (', pole_velikost_pameti, ' > ', maxavail, ')');
    exit;
  end;

  getmem(pole, pole_velikost_pameti);

  for i := 1 to pole_pocet_prvku do
    pole^[i] := i;
  for i :=  1 to pole_pocet_prvku do
    writeln('#', i, ':', pole^[i]);

  freemem(pole, pole_velikost_pameti);
end.

I když ty asi dynamickou alokaci stejně nepotřebuješ.

const
  MAX = 10000;

var
  pole: array [1..MAX] of integer;
  pole_pocet_prvku, i: longint;

begin
  pole_pocet_prvku := 5000;

  if pole_pocet_prvku > MAX then
  begin
    writeln('To je moc! (max ', MAX, ')');
    exit;
  end;

  for i := 1 to pole_pocet_prvku do
    pole[i] := i;
  for i :=  1 to pole_pocet_prvku do
    writeln('#', i, ':', pole[i]);
end.

Děkuji mnohokrát, zítra vyzkouším a dám vědět, jak to dopadlo.