TIP: Přetáhni ikonu na hlavní panel pro připnutí webu
V tomto článku hodlám rozebrat problematiku obsluhy jednoduché maticové klávesnice 3×4 tlačítka. Bude zde rozveden postup připojení k mikroprocesoru (jednochipu), detailnější rozbor vlastní obsluhy a také příklad programu pro x51. Tento příklad můžete využít při tvorbě vlastní aplikace, popřípadě si jej libovolně modifikovat pro vlastní účely.
Při návrhu jednodušších aplikací, založených na mikroprocesorovém systému, vyvstane pro mnoho návrhářů potřeba zadávat vstupní parametry za použití klávesnice. Předmětem tohoto článku je rozbor problému komunikace s „číselníkovou“ klávesnicí. Tento typ klávesnice lze nalézt například na veřejných telefonních automatech, na různých terminálech, zabezpečovacích zařízeních (kódové zámky) apod. Použití tohoto vstupního zařízení může nalézt uplatnění ve vašich vlastních zařízeních (kódové zámky, ovládací panely, propojení s PC atd.). Fantazii se zkrátka meze nekladou.
Princip této klávesnice není nikterak složitý. Představte si ji jako síť izolovaných vodičů o třech sloupcích a čtyřech řadách, přičemž v každé uzlové poloze (tj. v místě, kde se protíná řádek se sloupcem) se nachází tlačítko. Tudíž principem je, že každé tlačítko je jednoznačně identifikováno polohou v řádku a sloupci (resp. jejich propojením). Proto se také toto uspořádání nazývá maticové.
Způsob připojení klávesnice k mikropočítači
Příklad připojení klávesnice k mikropočítači (v našem případě 89c2051) je uveden níže. Uvedené zapojení se ukázalo jako nejvýhodnější. Z principu je nutno zapojit jak sloupce, tak řádky této matice.
V tomto příkladu je použita klávesnice 3×4, tím pádem pokud ji zapojíme na 8-bit. port, zbude nám nám ještě jeden pin. Tento I/O procesoru můžeme použít pro naše další účely (Led, beeper atp.). V programu však není ošetřeno jeho vymaskování, které byste si museli sami přidat. Rovněž je zde možnost použít maticovou klávesnici 4×4, v takovém případě by bylo nutné rovněž drobně upravit program.
Popis přístupu k datům z klávesnice
Postupujeme tak, že postupně aktivujeme jednotlivé sloupce (vystavením logické nuly) a poté čteme (naráz) řádky. Pokud je stisknuto nějaké tlačítko, objeví se log. nula také na příslušném řádku. Toto je základní a nejdůležitější poznatek, z kterého se musí vycházet při tvorbě obslužného programu.
Mohou nastat i situace, kdy je například v jednom okamžiku stisknuto více tlačítek, ale to je nestandardní a nechť se s tím každý vypořádá po svém.
Výpis programu
;******************************************
;PODPROGRAM CTE MAT.KLAVESNICI,VYST.JE V A
;
; PROGRAMED BY VAGOVSZKYM -
; VAGOVSZKYM[AT]CENTRUM[DOT]CZ
;******************************************
KLAV: CALL REAAD ;KLAV REALIZUJE FCI
CLR C ;CEKANI NA STISK KLAV
RLC A ;VE SMYCCE, LZE
JC KLAV ;VYNECHAT, PAK SE
RRC A ;POUZIJE REAAD, KTERY
PUSH ACC ;ZKOUMA PRAVE
CI1: CALL REAAD ;STISKNUTOU KLAVESU
RLC A
JNC CI1
POP ACC
RET
;-----------------------------------------
REAAD: MOV P1,#11111110B
MOV A,P1
CJNE A,#11101110B,L3
MOV A,#3D ;HODNOTA PRO KL. 3
RET
L3: CJNE A,#11011110B,L6
MOV A,#6D ;HODNOTA PRO KL. 6
RET
L6: CJNE A,#10111110B,L9
MOV A,#9D ;HODNOTA PRO KL. 9
RET
L9: CJNE A,#01111110B,LB
MOV A,#0BH ;HODNOTA PRO KL. B
RET
LB: MOV P1,#11111101B
MOV A,P1
CJNE A,#11101101B,L2
MOV A,#2D ;ATD
RET
L2: CJNE A,#11011101B,L5
MOV A,#5D
RET
L5: CJNE A,#10111101B,L8
MOV A,#8D
RET
L8: CJNE A,#01111101B,L0
MOV A,#0D
RET
L0: MOV P1,#11111011B
MOV A,P1
CJNE A,#11101011B,L1
MOV A,#1D
RET
L1: CJNE A,#11011011B,L4
MOV A,#4D
RET
L4: CJNE A,#10111011B,L7
MOV A,#7D
RET
L7: CJNE A,#01111011B,LA
MOV A,#0AH
RET
LA: MOV A,#0FFH ;POKUD PRI FCI
RET ;REAAD NENI STISK.
;KLAVESA -> 0FFH
;------------------------------------------
